Update Dynamic Ip Noip.com Melalui Mikrotik

Langsung saja, ada beberapa website penyedia layanan untuk update dynamic ip salah satu yang aku pakai adalah dari noip.com, kenapa jadi favorit yang jelas karena GRATISAN ūüėÄ .

Untuk update dynamic ip melalui Mikrotik, sangat dibutuhkan script untuk cek ip terbaru dan secara otomatis mengupdatenya ke layanan noip.com. Berikut scriptnya :

# No-IP automatic Dynamic DNS update

#--------------- Change Values in this section to match your setup ------------------

# No-IP User account info
:local noipuser "your_no-ip_user"
:local noippass "your_no-ip_pass"

# Set the hostname or label of network to be updated.
# Hostnames with spaces are unsupported. Replace the value in the quotations below with your host names.
# To specify multiple hosts, separate them with commas.
:local noiphost "hostname.no-ip.net"

# Change to the name of interface that gets the dynamic IP address
:local inetinterface "your_external_interface"

#------------------------------------------------------------------------------------
# No more changes need

:global previousIP

:if ([/interface get $inetinterface value-name=running]) do={
# Get the current IP on the interface
   :local currentIP [/ip address get [find interface="$inetinterface" disabled=no] address]

# Strip the net mask off the IP address
   :for i from=( [:len $currentIP] - 1) to=0 do={
       :if ( [:pick $currentIP $i] = "/") do={ 
           :set currentIP [:pick $currentIP 0 $i]
       } 
   }

   :if ($currentIP != $previousIP) do={
       :log info "No-IP: Current IP $currentIP is not equal to previous IP, update needed"
       :set previousIP $currentIP

# The update URL. Note the "\3F" is hex for question mark (?). Required since ? is a special character in commands.
       :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"
       :local noiphostarray
       :set noiphostarray [:toarray $noiphost]
       :foreach host in=$noiphostarray do={
           :log info "No-IP: Sending update for $host"
           /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http dst-path=("no-ip_ddns_update-" . $host . ".txt")
           :log info "No-IP: Host $host updated on No-IP with IP $currentIP"
       }
   }  else={
       :log info "No-IP: Previous IP $previousIP is equal to current IP, no update needed"
   }
} else={
   :log info "No-IP: $inetinterface is not currently running, so therefore will not update."
}

 

Untuk :local inetinterface adalah interface externalnya bukan interface local yang mengarah pada modem speedynya.

Semoga bermanfaat ….

 

Related Search

Tags: #IP #terbaru #URL #website

Anda sedang membaca artikel tentang Update Dynamic Ip Noip.com Melalui Mikrotik. Silahkan baca artikel Be Log tentang Mikrotik, Tutorial lainnya. Semoga bermanfaat ...

Mikrotik Duckdns.org Update (New Script)
Mikrotik Duckdns.org Update (New Script)
Entah kenapa script untuk update Dynamic IP
Mengatasi Stiker Whatsapp Yang Tidak Muncul Di Android
Mengatasi Stiker Whatsapp Yang Tidak Muncul Di Android
Wahtsapp baru-baru ini merelease stiker untuk penggunanya,
SSL Gratis Dari LetsEncrypt
SSL Gratis Dari LetsEncrypt
Untuk mendapatkan SSL Ceritificate mungkin tidaklah semurah
Setup Storage Path The Dude di RB750G r3
Setup Storage Path The Dude di RB750G r3
The Dude merupakan tool yang cukup penting

Top